Rename QtMultimediaKit to QtMultimedia.

There are a few legacy bits left in place so it passes CI, and then qt5.git etc can be updated. Change-Id: I6b082e50e6958c72fdabc2974992e16d90dafa3a Reviewed-on: http://codereview.qt-project.org/5368 Reviewed-by: Qt Sanity Bot <qt_sanity_bot@ovi.com> Reviewed-by: Jonas Rabbe <jonas.rabbe@nokia.com>
2011-10-06 14:31:58 +10:00
parent 55bc4f2b46
commit 03f22bcdaf
395 changed files with 1393 additions and 3088 deletions
--- a/src/multimedia/audio/audio.pri
+++ b/src/multimedia/audio/audio.pri
@@ -0,0 +1,60 @@
+INCLUDEPATH += audio
+
+PUBLIC_HEADERS += audio/qaudio.h \
+           audio/qaudioformat.h \
+           audio/qaudioinput.h \
+           audio/qaudiooutput.h \
+           audio/qaudiodeviceinfo.h \
+           audio/qaudiosystemplugin.h \
+           audio/qaudiosystem.h 
+
+PRIVATE_HEADERS += audio/qaudiodevicefactory_p.h audio/qaudiopluginloader_p.h
+
+
+SOURCES += audio/qaudio.cpp \
+           audio/qaudioformat.cpp  \
+           audio/qaudiodeviceinfo.cpp \
+           audio/qaudiooutput.cpp \
+           audio/qaudioinput.cpp \
+           audio/qaudiosystemplugin.cpp \
+           audio/qaudiosystem.cpp \
+           audio/qaudiodevicefactory.cpp \
+           audio/qaudiopluginloader.cpp
+
+mac {
+    PRIVATE_HEADERS +=  audio/qaudioinput_mac_p.h \
+                audio/qaudiooutput_mac_p.h \
+                audio/qaudiodeviceinfo_mac_p.h \
+                audio/qaudio_mac_p.h
+
+    SOURCES += audio/qaudiodeviceinfo_mac_p.cpp \
+               audio/qaudiooutput_mac_p.cpp \
+               audio/qaudioinput_mac_p.cpp \
+               audio/qaudio_mac.cpp
+
+    LIBS += -framework ApplicationServices -framework CoreAudio -framework AudioUnit -framework AudioToolbox
+}
+
+win32 {
+    PRIVATE_HEADERS += audio/qaudioinput_win32_p.h audio/qaudiooutput_win32_p.h audio/qaudiodeviceinfo_win32_p.h
+    SOURCES += audio/qaudiodeviceinfo_win32_p.cpp \
+               audio/qaudiooutput_win32_p.cpp \
+               audio/qaudioinput_win32_p.cpp
+    LIBS += -lwinmm -lstrmiids -lole32 -loleaut32
+}
+
+unix:!mac {
+    contains(config_test_pulseaudio, yes) {
+        DEFINES += QT_NO_AUDIO_BACKEND
+    }
+    else:contains(QT_CONFIG, alsa) {
+        linux-*|freebsd-*|openbsd-* {
+            DEFINES += HAS_ALSA
+            PRIVATE_HEADERS += audio/qaudiooutput_alsa_p.h audio/qaudioinput_alsa_p.h audio/qaudiodeviceinfo_alsa_p.h
+            SOURCES += audio/qaudiodeviceinfo_alsa_p.cpp \
+                   audio/qaudiooutput_alsa_p.cpp \
+                   audio/qaudioinput_alsa_p.cpp
+            LIBS_PRIVATE += -lasound
+        }
+    }
+}