Initial copy of QtMultimediaKit.

Comes from original repo, with SHA1: 2c82d5611655e5967f5c5095af50c0991c4378b2
2011-06-29 13:38:46 +10:00
commit 2a34e88c1e
1048 changed files with 206259 additions and 0 deletions
--- a/src/plugins/gstreamer/gstreamer.pro
+++ b/src/plugins/gstreamer/gstreamer.pro
@@ -0,0 +1,101 @@
+
+load(qt_module)
+
+TARGET = qgstengine
+QT += multimediakit-private network
+PLUGIN_TYPE=mediaservice
+
+load(qt_plugin)
+DESTDIR = $$QT.multimediakit.plugins/$${PLUGIN_TYPE}
+
+unix:contains(QT_CONFIG, alsa) {
+DEFINES += HAVE_ALSA
+LIBS += \
+    -lasound
+}
+
+CONFIG += link_pkgconfig
+
+PKGCONFIG += \
+    gstreamer-0.10 \
+    gstreamer-base-0.10 \
+    gstreamer-interfaces-0.10 \
+    gstreamer-audio-0.10 \
+    gstreamer-video-0.10
+
+maemo*:PKGCONFIG +=gstreamer-plugins-bad-0.10
+contains(gstreamer-appsrc_enabled, yes): PKGCONFIG += gstreamer-app-0.10
+
+maemo5 {
+  HEADERS += camerabuttonlistener_maemo.h
+  SOURCES += camerabuttonlistener_maemo.cpp
+
+  QT += dbus
+}
+
+maemo6 {
+    HEADERS += camerabuttonlistener_meego.h
+    SOURCES += camerabuttonlistener_meego.cpp
+
+    PKGCONFIG += qmsystem2 libresourceqt1
+
+    isEqual(QT_ARCH,armv6) {
+        HEADERS += qgstreamergltexturerenderer.h
+        SOURCES += qgstreamergltexturerenderer.cpp
+        QT += opengl
+        LIBS += -lEGL -lgstmeegointerfaces-0.10
+    }
+}
+
+# Input
+HEADERS += \
+    qgstreamermessage.h \
+    qgstreamerbushelper.h \
+    qgstreamervideorendererinterface.h \
+    qgstreamerserviceplugin.h \
+    qgstreameraudioinputendpointselector.h \
+    qgstreamervideorenderer.h \
+    qgstvideobuffer.h \
+    qvideosurfacegstsink.h \
+    qgstreamervideoinputdevicecontrol.h \
+    gstvideoconnector.h \
+    qabstractgstbufferpool.h \
+    qgstutils.h
+
+SOURCES += \
+    qgstreamermessage.cpp \
+    qgstreamerbushelper.cpp \
+    qgstreamervideorendererinterface.cpp \
+    qgstreamerserviceplugin.cpp \
+    qgstreameraudioinputendpointselector.cpp \
+    qgstreamervideorenderer.cpp \
+    qgstvideobuffer.cpp \
+    qvideosurfacegstsink.cpp \
+    qgstreamervideoinputdevicecontrol.cpp \
+    gstvideoconnector.c \
+    qgstutils.cpp
+
+
+!win32:!contains(QT_CONFIG,embedded):!mac:!symbian:!simulator:!contains(QT_CONFIG, qpa) {
+    LIBS += -lXv -lX11 -lXext
+
+    HEADERS += \
+        qgstreamervideooverlay.h \
+        qgstreamervideowindow.h \
+        qgstreamervideowidget.h \
+        qx11videosurface.h \
+        qgstxvimagebuffer.h
+
+    SOURCES += \
+        qgstreamervideooverlay.cpp \
+        qgstreamervideowindow.cpp \
+        qgstreamervideowidget.cpp \
+        qx11videosurface.cpp \
+        qgstxvimagebuffer.cpp
+}
+include(mediaplayer/mediaplayer.pri)
+include(mediacapture/mediacapture.pri)
+
+contains(gstreamer-photography_enabled, yes) {
+    include(camerabin/camerabin.pri)
+}