Moved general gstreamer helper classes into separate library.

Cleaned up configuration of gstreamer with a separate config
test.

Change-Id: I1ec9ee466233687fbcfdc544a12d9fce578e4379
Reviewed-on: http://codereview.qt-project.org/6459
Sanity-Review: Qt Sanity Bot <qt_sanity_bot@ovi.com>
Reviewed-by: Michael Goddard <michael.goddard@nokia.com>

src/gsttools/gsttools.pro

@@ -0,0 +1,67 @@
+TEMPLATE = lib
+
+TARGET = qgsttools_p
+QPRO_PWD = $$PWD
+QT = core multimedia
+
+!static:DEFINES += QT_MAKEDLL
+
+unix:!maemo*:contains(QT_CONFIG, alsa) {
+DEFINES += HAVE_ALSA
+LIBS += \
+    -lasound
+}
+
+CONFIG += link_pkgconfig
+
+PKGCONFIG += \
+    gstreamer-0.10 \
+    gstreamer-base-0.10 \
+    gstreamer-interfaces-0.10 \
+    gstreamer-audio-0.10 \
+    gstreamer-video-0.10 \
+    gstreamer-pbutils-0.10
+
+maemo*:PKGCONFIG +=gstreamer-plugins-bad-0.10
+contains(config_test_gstreamer_appsrc, yes): PKGCONFIG += gstreamer-app-0.10
+
+contains(config_test_resourcepolicy, yes) {
+    DEFINES += HAVE_RESOURCE_POLICY
+    PKGCONFIG += libresourceqt1
+}
+
+# Header files must go inside source directory of a module
+# to be installed by syncqt.
+INCLUDEPATH += ../multimedia/gsttools_headers/
+DEPENDPATH += ../multimedia/gsttools_headers/
+
+PRIVATE_HEADERS += \
+    qabstractgstbufferpool_p.h \
+    qgstreamerbushelper_p.h \
+    qgstreamermessage_p.h \
+    qgstutils_p.h \
+    qgstvideobuffer_p.h \
+    qvideosurfacegstsink_p.h \
+
+SOURCES += \
+    qgstreamerbushelper.cpp \
+    qgstreamermessage.cpp \
+    qgstutils.cpp \
+    qgstvideobuffer.cpp \
+    qvideosurfacegstsink.cpp \
+
+!win32:!contains(QT_CONFIG,embedded):!mac:!simulator:!contains(QT_CONFIG, qpa) {
+    LIBS += -lXv -lX11 -lXext
+
+    PRIVATE_HEADERS += \
+        qgstxvimagebuffer_p.h \
+
+
+    SOURCES += \
+        qgstxvimagebuffer.cpp \
+}
+
+HEADERS += $$PRIVATE_HEADERS
+
+DESTDIR = $$QT.multimedia.libs
+