centralize and fixup example sources install targets
This follows suit with aeb036e in qtbase. Change-Id: Ie8580d0a1f38ab9858b0e44c9f99bdc552a1752a Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@digia.com> Reviewed-by: hjk <qthjk@ovi.com>
This commit is contained in:
Joerg Bornemann
committed by
The Qt Project
The Qt Project
parent
90c8ba233b
commit
6b4994c265
183
examples/multimedia/video/qmlvideofx/shaders/pagecurl.fsh
Normal file
183
examples/multimedia/video/qmlvideofx/shaders/pagecurl.fsh
Normal file
@@ -0,0 +1,183 @@
|
||||
/****************************************************************************
|
||||
**
|
||||
** Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
|
||||
** Contact: http://www.qt-project.org/legal
|
||||
**
|
||||
** This file is part of the Qt Mobility Components.
|
||||
**
|
||||
** $QT_BEGIN_LICENSE:LGPL$
|
||||
** Commercial License Usage
|
||||
** Licensees holding valid commercial Qt licenses may use this file in
|
||||
** accordance with the commercial license agreement provided with the
|
||||
** Software or, alternatively, in accordance with the terms contained in
|
||||
** a written agreement between you and Digia. For licensing terms and
|
||||
** conditions see http://qt.digia.com/licensing. For further information
|
||||
** use the contact form at http://qt.digia.com/contact-us.
|
||||
**
|
||||
** GNU Lesser General Public License Usage
|
||||
** Alternatively, this file may be used under the terms of the GNU Lesser
|
||||
** General Public License version 2.1 as published by the Free Software
|
||||
** Foundation and appearing in the file LICENSE.LGPL included in the
|
||||
** packaging of this file. Please review the following information to
|
||||
** ensure the GNU Lesser General Public License version 2.1 requirements
|
||||
** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
|
||||
**
|
||||
** In addition, as a special exception, Digia gives you certain additional
|
||||
** rights. These rights are described in the Digia Qt LGPL Exception
|
||||
** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
|
||||
**
|
||||
** GNU General Public License Usage
|
||||
** Alternatively, this file may be used under the terms of the GNU
|
||||
** General Public License version 3.0 as published by the Free Software
|
||||
** Foundation and appearing in the file LICENSE.GPL included in the
|
||||
** packaging of this file. Please review the following information to
|
||||
** ensure the GNU General Public License version 3.0 requirements will be
|
||||
** met: http://www.gnu.org/copyleft/gpl.html.
|
||||
**
|
||||
**
|
||||
** $QT_END_LICENSE$
|
||||
**
|
||||
****************************************************************************/
|
||||
|
||||
// Based on http://rectalogic.github.com/webvfx/examples_2transition-shader-pagecurl_8html-example.html
|
||||
|
||||
uniform float dividerValue;
|
||||
uniform float curlExtent;
|
||||
uniform sampler2D source;
|
||||
uniform lowp float qt_Opacity;
|
||||
varying vec2 qt_TexCoord0;
|
||||
|
||||
const float minAmount = -0.16;
|
||||
const float maxAmount = 1.3;
|
||||
const float PI = 3.141592653589793;
|
||||
const float scale = 512.0;
|
||||
const float sharpness = 3.0;
|
||||
const vec4 bgColor = vec4(1.0, 1.0, 0.8, 1.0);
|
||||
|
||||
float amount = curlExtent * (maxAmount - minAmount) + minAmount;
|
||||
float cylinderCenter = amount;
|
||||
// 360 degrees * amount
|
||||
float cylinderAngle = 2.0 * PI * amount;
|
||||
const float cylinderRadius = 1.0 / PI / 2.0;
|
||||
|
||||
vec3 hitPoint(float hitAngle, float yc, vec3 point, mat3 rrotation)
|
||||
{
|
||||
float hitPoint = hitAngle / (2.0 * PI);
|
||||
point.y = hitPoint;
|
||||
return rrotation * point;
|
||||
}
|
||||
|
||||
vec4 antiAlias(vec4 color1, vec4 color2, float distance)
|
||||
{
|
||||
distance *= scale;
|
||||
if (distance < 0.0) return color2;
|
||||
if (distance > 2.0) return color1;
|
||||
float dd = pow(1.0 - distance / 2.0, sharpness);
|
||||
return ((color2 - color1) * dd) + color1;
|
||||
}
|
||||
|
||||
float distanceToEdge(vec3 point)
|
||||
{
|
||||
float dx = abs(point.x > 0.5 ? 1.0 - point.x : point.x);
|
||||
float dy = abs(point.y > 0.5 ? 1.0 - point.y : point.y);
|
||||
if (point.x < 0.0) dx = -point.x;
|
||||
if (point.x > 1.0) dx = point.x - 1.0;
|
||||
if (point.y < 0.0) dy = -point.y;
|
||||
if (point.y > 1.0) dy = point.y - 1.0;
|
||||
if ((point.x < 0.0 || point.x > 1.0) && (point.y < 0.0 || point.y > 1.0)) return sqrt(dx * dx + dy * dy);
|
||||
return min(dx, dy);
|
||||
}
|
||||
|
||||
vec4 seeThrough(float yc, vec2 p, mat3 rotation, mat3 rrotation)
|
||||
{
|
||||
float hitAngle = PI - (acos(yc / cylinderRadius) - cylinderAngle);
|
||||
vec3 point = hitPoint(hitAngle, yc, rotation * vec3(p, 1.0), rrotation);
|
||||
if (yc <= 0.0 && (point.x < 0.0 || point.y < 0.0 || point.x > 1.0 || point.y > 1.0))
|
||||
return bgColor;
|
||||
if (yc > 0.0)
|
||||
return texture2D(source, p);
|
||||
vec4 color = texture2D(source, point.xy);
|
||||
vec4 tcolor = vec4(0.0);
|
||||
return antiAlias(color, tcolor, distanceToEdge(point));
|
||||
}
|
||||
|
||||
vec4 seeThroughWithShadow(float yc, vec2 p, vec3 point, mat3 rotation, mat3 rrotation)
|
||||
{
|
||||
float shadow = distanceToEdge(point) * 30.0;
|
||||
shadow = (1.0 - shadow) / 3.0;
|
||||
if (shadow < 0.0)
|
||||
shadow = 0.0;
|
||||
else
|
||||
shadow *= amount;
|
||||
vec4 shadowColor = seeThrough(yc, p, rotation, rrotation);
|
||||
shadowColor.r -= shadow;
|
||||
shadowColor.g -= shadow;
|
||||
shadowColor.b -= shadow;
|
||||
return shadowColor;
|
||||
}
|
||||
|
||||
vec4 backside(float yc, vec3 point)
|
||||
{
|
||||
vec4 color = texture2D(source, point.xy);
|
||||
float gray = (color.r + color.b + color.g) / 15.0;
|
||||
gray += (8.0 / 10.0) * (pow(1.0 - abs(yc / cylinderRadius), 2.0 / 10.0) / 2.0 + (5.0 / 10.0));
|
||||
color.rgb = vec3(gray);
|
||||
return color;
|
||||
}
|
||||
|
||||
void main(void)
|
||||
{
|
||||
const float angle = 30.0 * PI / 180.0;
|
||||
float c = cos(-angle);
|
||||
float s = sin(-angle);
|
||||
mat3 rotation = mat3(
|
||||
c, s, 0,
|
||||
-s, c, 0,
|
||||
0.12, 0.258, 1
|
||||
);
|
||||
c = cos(angle);
|
||||
s = sin(angle);
|
||||
mat3 rrotation = mat3(
|
||||
c, s, 0,
|
||||
-s, c, 0,
|
||||
0.15, -0.5, 1
|
||||
);
|
||||
vec3 point = rotation * vec3(qt_TexCoord0, 1.0);
|
||||
float yc = point.y - cylinderCenter;
|
||||
vec4 color = vec4(1.0, 0.0, 0.0, 1.0);
|
||||
if (yc < -cylinderRadius) {
|
||||
// See through to background
|
||||
color = bgColor;
|
||||
} else if (yc > cylinderRadius) {
|
||||
// Flat surface
|
||||
color = texture2D(source, qt_TexCoord0);
|
||||
} else {
|
||||
float hitAngle = (acos(yc / cylinderRadius) + cylinderAngle) - PI;
|
||||
float hitAngleMod = mod(hitAngle, 2.0 * PI);
|
||||
if ((hitAngleMod > PI && amount < 0.5) || (hitAngleMod > PI/2.0 && amount < 0.0)) {
|
||||
color = seeThrough(yc, qt_TexCoord0, rotation, rrotation);
|
||||
} else {
|
||||
point = hitPoint(hitAngle, yc, point, rrotation);
|
||||
if (point.x < 0.0 || point.y < 0.0 || point.x > 1.0 || point.y > 1.0) {
|
||||
color = seeThroughWithShadow(yc, qt_TexCoord0, point, rotation, rrotation);
|
||||
} else {
|
||||
color = backside(yc, point);
|
||||
vec4 otherColor;
|
||||
if (yc < 0.0) {
|
||||
float shado = 1.0 - (sqrt(pow(point.x - 0.5, 2.0) + pow(point.y - 0.5, 2.0)) / 0.71);
|
||||
shado *= pow(-yc / cylinderRadius, 3.0);
|
||||
shado *= 0.5;
|
||||
otherColor = vec4(0.0, 0.0, 0.0, shado);
|
||||
} else {
|
||||
otherColor = texture2D(source, qt_TexCoord0);
|
||||
}
|
||||
color = antiAlias(color, otherColor, cylinderRadius - abs(yc));
|
||||
|
||||
// This second antialiasing step causes the shader to fail to render, on
|
||||
// Symbian devices (tested so far using IVE3.5). Running out of scratch
|
||||
// memory?
|
||||
}
|
||||
}
|
||||
}
|
||||
gl_FragColor = qt_Opacity * color;
|
||||
}
|
||||
Reference in New Issue
Block a user