Merge demos and examples.

Change-Id: I65ba412ef5207a71bf8763983b28672d1743f4b8
Reviewed-on: http://codereview.qt.nokia.com/1398
Reviewed-by: Qt Sanity Bot <qt_sanity_bot@ovi.com>
Reviewed-by: Casper van Donderen <casper.vandonderen@nokia.com>

examples/multimedia/spectrum/3rdparty/fftreal/fftreal.pro

@@ -0,0 +1,52 @@
+include(../../spectrum.pri)
+
+static: error(This library cannot be built for static linkage)
+
+TEMPLATE = lib
+TARGET   = fftreal
+
+# FFTReal
+HEADERS  += Array.h \
+            Array.hpp \
+            DynArray.h \
+            DynArray.hpp \
+            FFTRealFixLen.h \
+            FFTRealFixLen.hpp \
+            FFTRealFixLenParam.h \
+            FFTRealPassDirect.h \
+            FFTRealPassDirect.hpp \
+            FFTRealPassInverse.h \
+            FFTRealPassInverse.hpp \
+            FFTRealSelect.h \
+            FFTRealSelect.hpp \
+            FFTRealUseTrigo.h \
+            FFTRealUseTrigo.hpp \
+            OscSinCos.h \
+            OscSinCos.hpp \
+            def.h
+	    
+# Wrapper used to export the required instantiation of the FFTRealFixLen template
+HEADERS  += fftreal_wrapper.h
+SOURCES  += fftreal_wrapper.cpp
+
+DEFINES  += FFTREAL_LIBRARY
+
+symbian {
+    # Provide unique ID for the generated binary, required by Symbian OS
+    TARGET.UID3 = 0xA000E403
+    TARGET.CAPABILITY = UserEnvironment
+}
+
+macx {
+    CONFIG += lib_bundle
+} else {
+    !symbian: DESTDIR = ../..$${spectrum_build_dir}
+}
+
+# Install
+
+sources.files = $$SOURCES $$HEADERS fftreal.pro readme.txt license.txt
+sources.files += bwins/fftreal.def eabi/fftreal.def
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/multimedia/spectrum/3rdparty/fftreal
+INSTALLS += sources
+