041e75d1c0
No all QNX versions/variations have a mmrenderer by default, so we need to check for it, otherwise it fails to compile. Change-Id: I3efe9df37cf7807c1b0ac4d2e8f49aa02e3408cd Reviewed-by: Frank Osterfeld <frank.osterfeld@kdab.com> Reviewed-by: Rafael Roquetto <rafael.roquetto@kdab.com> Reviewed-by: Lars Knoll <lars.knoll@digia.com>
34 lines
879 B
Prolog
34 lines
879 B
Prolog
requires(qtHaveModule(gui))
|
|
|
|
load(configure)
|
|
qtCompileTest(openal)
|
|
win32 {
|
|
qtCompileTest(directshow) {
|
|
qtCompileTest(wshellitem)
|
|
}
|
|
qtCompileTest(wmsdk)
|
|
qtCompileTest(wmp)
|
|
contains(QT_CONFIG, wmf-backend): qtCompileTest(wmf)
|
|
qtCompileTest(evr)
|
|
} else:mac {
|
|
qtCompileTest(avfoundation)
|
|
} else:android {
|
|
SDK_ROOT = $$(ANDROID_SDK_ROOT)
|
|
isEmpty(SDK_ROOT): SDK_ROOT = $$DEFAULT_ANDROID_SDK_ROOT
|
|
!exists($$SDK_ROOT/platforms/android-11/android.jar): error("QtMultimedia for Android requires API level 11")
|
|
} else:qnx {
|
|
qtCompileTest(mmrenderer)
|
|
} else {
|
|
qtCompileTest(alsa)
|
|
qtCompileTest(pulseaudio)
|
|
qtCompileTest(gstreamer) {
|
|
qtCompileTest(gstreamer_photography)
|
|
qtCompileTest(gstreamer_encodingprofiles)
|
|
qtCompileTest(gstreamer_appsrc)
|
|
}
|
|
qtCompileTest(resourcepolicy)
|
|
}
|
|
|
|
load(qt_parts)
|
|
|