c3ca3a760e
Removed QGstreamerVideoOverlay and related classes. It was used as 'Window' control but performs worse than QGstreamerVideoWindow which does basically the same thing using GStreamer ready-made components instead. Removed X11 dependencies and related configuration tests. It was only needed for QGstreamerVideoOverlay. Change-Id: I2ad2636ccf0060e56cd64f3d9e5b3c24dc75f5a3 Reviewed-by: Andy Nichols <andy.nichols@digia.com>
31 lines
818 B
Prolog
31 lines
818 B
Prolog
requires(qtHaveModule(gui))
|
|
|
|
load(configure)
|
|
qtCompileTest(openal)
|
|
qtCompileTest(opensles)
|
|
win32 {
|
|
qtCompileTest(directshow)
|
|
qtCompileTest(wmsdk)
|
|
qtCompileTest(wmp)
|
|
contains(QT_CONFIG, wmf-backend): qtCompileTest(wmf)
|
|
qtCompileTest(evr)
|
|
} else:mac {
|
|
qtCompileTest(avfoundation)
|
|
} else:android {
|
|
SDK_ROOT = $$(ANDROID_SDK_ROOT)
|
|
isEmpty(SDK_ROOT): SDK_ROOT = $$DEFAULT_ANDROID_SDK_ROOT
|
|
!exists($$SDK_ROOT/platforms/android-11/android.jar): error("QtMultimedia for Android requires API level 11")
|
|
} else {
|
|
qtCompileTest(alsa)
|
|
qtCompileTest(pulseaudio)
|
|
qtCompileTest(gstreamer) {
|
|
qtCompileTest(gstreamer_photography)
|
|
qtCompileTest(gstreamer_encodingprofiles)
|
|
qtCompileTest(gstreamer_appsrc)
|
|
}
|
|
qtCompileTest(resourcepolicy)
|
|
}
|
|
|
|
load(qt_parts)
|
|
|