ea1037a7d0
Use Q_PROCESSOR_ARM instead of QT_ARCH_ARM. On maemo6, don't use QT_ARCH==armv6 to conditionally include egl code. Instead check for opengles2 in QT_CONFIG, which is detected by the configure script. Change-Id: Ib3062fbd81c3a3acd318df32c49ad133a5b0d07c Reviewed-by: Michael Goddard <michael.goddard@nokia.com>
70 lines
1.5 KiB
Prolog
70 lines
1.5 KiB
Prolog
load(qt_module)
|
|
|
|
# distinct from QtMultimedia
|
|
TARGET = QtMultimediaWidgets
|
|
QPRO_PWD = $$PWD
|
|
QT = core gui multimedia-private widgets-private
|
|
|
|
CONFIG += module no_private_qt_headers_warning
|
|
MODULE_PRI += ../../modules/qt_multimediawidgets.pri
|
|
|
|
contains(QT_CONFIG, opengl) | contains(QT_CONFIG, opengles2) {
|
|
QT += opengl
|
|
} else {
|
|
DEFINES += QT_NO_OPENGL
|
|
}
|
|
|
|
!static:DEFINES += QT_MAKEDLL
|
|
DEFINES += QT_BUILD_MULTIMEDIAWIDGETS_LIB
|
|
|
|
load(qt_module_config)
|
|
|
|
PRIVATE_HEADERS += \
|
|
qvideowidget_p.h \
|
|
qpaintervideosurface_p.h \
|
|
|
|
PUBLIC_HEADERS += \
|
|
qtmultimediawidgetdefs.h \
|
|
qtmultimediawidgetsversion.h \
|
|
qcameraviewfinder.h \
|
|
qgraphicsvideoitem.h \
|
|
qvideowidgetcontrol.h \
|
|
qvideowidget.h \
|
|
qvideowindowcontrol.h
|
|
|
|
SOURCES += \
|
|
qcameraviewfinder.cpp \
|
|
qpaintervideosurface.cpp \
|
|
qvideowidgetcontrol.cpp \
|
|
qvideowidget.cpp \
|
|
qvideowindowcontrol.cpp \
|
|
|
|
mac {
|
|
# QtWidgets is not yet supported on Mac (!).
|
|
false:!simulator {
|
|
PRIVATE_HEADERS += qpaintervideosurface_mac_p.h
|
|
OBJECTIVE_SOURCES += qpaintervideosurface_mac.mm
|
|
}
|
|
LIBS += -framework AppKit -framework QuartzCore -framework QTKit
|
|
}
|
|
|
|
maemo6 {
|
|
contains(QT_CONFIG, opengles2) {
|
|
PRIVATE_HEADERS += qeglimagetexturesurface_p.h
|
|
SOURCES += qeglimagetexturesurface.cpp
|
|
|
|
SOURCES += qgraphicsvideoitem_maemo6.cpp
|
|
|
|
LIBS += -lX11
|
|
} else {
|
|
SOURCES += qgraphicsvideoitem.cpp
|
|
}
|
|
}
|
|
|
|
!maemo* {
|
|
SOURCES += qgraphicsvideoitem.cpp
|
|
}
|
|
|
|
HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS
|
|
|