b1a4d7f9fc
- load(qt_module) => load(qt_build_config) - remove: - CONFIG+=module (obsolete) - code relating to module version headers (automated now) - %mastercontent assignment (automated now) - QT_BUILD_*_LIB defines (automated now) - pointless QPRO_PWD assignments - pointless DEFINES+=QT_MAKEDLL - pointless and commented out include and depend paths - qmake -project boilerplate Change-Id: I8f4586403848fe8f2dff4e889b389956ffcdea59 Reviewed-by: Jonas Rabbe <jonas.rabbe@gmail.com> Reviewed-by: Michael Goddard <michael.goddard@nokia.com>
63 lines
1.3 KiB
Prolog
63 lines
1.3 KiB
Prolog
load(qt_build_config)
|
|
|
|
# distinct from QtMultimedia
|
|
TARGET = QtMultimediaWidgets
|
|
QT = core gui multimedia-private widgets-private
|
|
|
|
CONFIG += no_private_qt_headers_warning
|
|
|
|
load(qt_module_config)
|
|
|
|
# private dependencies
|
|
contains(QT_CONFIG, opengl) | contains(QT_CONFIG, opengles2) {
|
|
QT += opengl
|
|
} else {
|
|
DEFINES += QT_NO_OPENGL
|
|
}
|
|
|
|
PRIVATE_HEADERS += \
|
|
qvideowidget_p.h \
|
|
qpaintervideosurface_p.h \
|
|
|
|
PUBLIC_HEADERS += \
|
|
qtmultimediawidgetdefs.h \
|
|
qcameraviewfinder.h \
|
|
qgraphicsvideoitem.h \
|
|
qvideowidgetcontrol.h \
|
|
qvideowidget.h
|
|
|
|
SOURCES += \
|
|
qcameraviewfinder.cpp \
|
|
qpaintervideosurface.cpp \
|
|
qvideowidgetcontrol.cpp \
|
|
qvideowidget.cpp
|
|
|
|
mac {
|
|
# QtWidgets is not yet supported on Mac (!).
|
|
false:!simulator {
|
|
PRIVATE_HEADERS += qpaintervideosurface_mac_p.h
|
|
OBJECTIVE_SOURCES += qpaintervideosurface_mac.mm
|
|
}
|
|
LIBS += -framework AppKit -framework QuartzCore -framework QTKit
|
|
}
|
|
|
|
maemo6 {
|
|
contains(QT_CONFIG, opengles2) {
|
|
PRIVATE_HEADERS += qeglimagetexturesurface_p.h
|
|
SOURCES += qeglimagetexturesurface.cpp
|
|
|
|
SOURCES += qgraphicsvideoitem_maemo6.cpp
|
|
|
|
LIBS += -lX11
|
|
} else {
|
|
SOURCES += qgraphicsvideoitem.cpp
|
|
}
|
|
}
|
|
|
|
!maemo* {
|
|
SOURCES += qgraphicsvideoitem.cpp
|
|
}
|
|
|
|
HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS
|
|
|