c97f5f8c2e
It does use a config test for now, just to make it clearer. The Mac backend currently requires widgets, but most of the others should work without it (just not supporting QVideoWidget/WindowControl). The QVideoDeviceControl interface was modified to remove the QIcon usage - it was never implemented. Unfortunately even the QML examples need widgets for the wrapper application, and will need to be ported to QtGui based wrapper. Change-Id: I8a55ad5cf09ab51749510bf16f49de0bd3f0bcdb Reviewed-by: Ling Hu <ling.hu@nokia.com>
103 lines
2.4 KiB
Prolog
103 lines
2.4 KiB
Prolog
|
|
load(qt_module)
|
|
|
|
TARGET = qgstengine
|
|
QT += multimedia-private network
|
|
CONFIG += no_private_qt_headers_warning
|
|
|
|
contains(config_test_widgets, yes) {
|
|
QT += widgets multimediawidgets-private
|
|
DEFINES += HAVE_WIDGETS
|
|
}
|
|
|
|
PLUGIN_TYPE=mediaservice
|
|
|
|
load(qt_plugin)
|
|
DESTDIR = $$QT.multimedia.plugins/$${PLUGIN_TYPE}
|
|
|
|
LIBS += -lqgsttools_p
|
|
|
|
unix:!maemo*:contains(QT_CONFIG, alsa) {
|
|
DEFINES += HAVE_ALSA
|
|
LIBS += -lasound
|
|
}
|
|
|
|
CONFIG += link_pkgconfig
|
|
|
|
PKGCONFIG += \
|
|
gstreamer-0.10 \
|
|
gstreamer-base-0.10 \
|
|
gstreamer-interfaces-0.10 \
|
|
gstreamer-audio-0.10 \
|
|
gstreamer-video-0.10 \
|
|
gstreamer-pbutils-0.10
|
|
|
|
maemo*:PKGCONFIG +=gstreamer-plugins-bad-0.10
|
|
contains(config_test_gstreamer_appsrc, yes): PKGCONFIG += gstreamer-app-0.10
|
|
|
|
contains(config_test_resourcepolicy, yes) {
|
|
DEFINES += HAVE_RESOURCE_POLICY
|
|
PKGCONFIG += libresourceqt1
|
|
}
|
|
|
|
maemo6 {
|
|
HEADERS += camerabuttonlistener_meego.h
|
|
SOURCES += camerabuttonlistener_meego.cpp
|
|
|
|
PKGCONFIG += qmsystem2
|
|
|
|
isEqual(QT_ARCH,armv6):contains(config_test_widgets, yes) {
|
|
HEADERS += qgstreamergltexturerenderer.h
|
|
SOURCES += qgstreamergltexturerenderer.cpp
|
|
QT += opengl
|
|
LIBS += -lEGL -lgstmeegointerfaces-0.10
|
|
}
|
|
}
|
|
|
|
# Input
|
|
HEADERS += \
|
|
qgstreamervideorendererinterface.h \
|
|
qgstreamerserviceplugin.h \
|
|
qgstreameraudioinputendpointselector.h \
|
|
qgstreamervideorenderer.h \
|
|
qgstreamervideoinputdevicecontrol.h \
|
|
gstvideoconnector.h \
|
|
qgstcodecsinfo.h \
|
|
|
|
SOURCES += \
|
|
qgstreamervideorendererinterface.cpp \
|
|
qgstreamerserviceplugin.cpp \
|
|
qgstreameraudioinputendpointselector.cpp \
|
|
qgstreamervideorenderer.cpp \
|
|
qgstreamervideoinputdevicecontrol.cpp \
|
|
qgstcodecsinfo.cpp \
|
|
gstvideoconnector.c \
|
|
|
|
|
|
contains(config_test_xvideo, yes):contains(config_test_widgets, yes): {
|
|
DEFINES += HAVE_XVIDEO
|
|
|
|
LIBS += -lXv -lX11 -lXext
|
|
|
|
HEADERS += \
|
|
qgstreamervideooverlay.h \
|
|
qgstreamervideowindow.h \
|
|
qgstreamervideowidget.h \
|
|
qx11videosurface.h \
|
|
|
|
SOURCES += \
|
|
qgstreamervideooverlay.cpp \
|
|
qgstreamervideowindow.cpp \
|
|
qgstreamervideowidget.cpp \
|
|
qx11videosurface.cpp \
|
|
}
|
|
include(mediaplayer/mediaplayer.pri)
|
|
include(mediacapture/mediacapture.pri)
|
|
|
|
contains(config_test_gstreamer_photography, yes) {
|
|
include(camerabin/camerabin.pri)
|
|
}
|
|
|
|
target.path += $$[QT_INSTALL_PLUGINS]/$${PLUGIN_TYPE}
|
|
INSTALLS += target
|