c97f5f8c2e
It does use a config test for now, just to make it clearer. The Mac backend currently requires widgets, but most of the others should work without it (just not supporting QVideoWidget/WindowControl). The QVideoDeviceControl interface was modified to remove the QIcon usage - it was never implemented. Unfortunately even the QML examples need widgets for the wrapper application, and will need to be ported to QtGui based wrapper. Change-Id: I8a55ad5cf09ab51749510bf16f49de0bd3f0bcdb Reviewed-by: Ling Hu <ling.hu@nokia.com>
31 lines
713 B
INI
31 lines
713 B
INI
TEMPLATE = subdirs
|
|
|
|
SUBDIRS += multimedia
|
|
|
|
# Everything else depends on multimedia
|
|
src_qgsttools.subdir = $$IN_PWD/gsttools
|
|
src_qgsttools.depends = multimedia
|
|
|
|
src_qtmmwidgets.subdir = $$IN_PWD/multimediawidgets
|
|
src_qtmmwidgets.depends = multimedia
|
|
|
|
src_plugins.subdir = $$IN_PWD/plugins
|
|
src_plugins.depends = multimedia
|
|
|
|
src_imports.subdir = $$IN_PWD/imports
|
|
src_imports.depends = multimedia
|
|
|
|
SUBDIRS += src_imports
|
|
|
|
# Optional bits
|
|
contains(config_test_gstreamer, yes):SUBDIRS += src_qgsttools
|
|
contains(config_test_widgets, yes) {
|
|
SUBDIRS += src_qtmmwidgets
|
|
|
|
# If widgets is around, plugins depends on widgets too (imports does not)
|
|
src_plugins.depends += src_qtmmwidgets
|
|
}
|
|
|
|
SUBDIRS += src_plugins
|
|
|