Fix building of examples.

- Correct install paths
- Add missing resources
- Add declarative-radio
- Remove deploy/install logic from qmlapplicationviewer.pri and
  snippet .pro-files of the video examples and add normal install
  rules.

Task-number: QTBUG-27977

Change-Id: Iadecb14d9330c752f6fb739918da743a854ba236
Reviewed-by: Christian Kandeler <christian.kandeler@digia.com>

examples/audiodecoder/audiodecoder.pro

@@ -12,3 +12,9 @@ SOURCES = main.cpp \
 
 QT += multimedia
 CONFIG += console
+
+# install
+target.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/audiodecoder
+sources.files = $$SOURCES $$HEADERS audiodecoder.pro
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/audiodecoder
+INSTALLS += target sources

examples/audioengine/audioengine.pro

@@ -2,8 +2,8 @@ TEMPLATE = subdirs
 
 # These examples contain no C++ and can simply be copied
 SUBDIRS =
-sources.files = qml/*
+sources.files = doc qml
-sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/declarative/audioengine
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/audioengine
 INSTALLS += sources
 
 OTHER_FILES += qml/*.qml qml/*.qmlproject qml/content/*

examples/customvideosurface/customvideoitem/customvideoitem.pro

@@ -12,8 +12,8 @@ SOURCES   += main.cpp \
              videoplayer.cpp \
              videoitem.cpp
 
-target.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/customvideoitem
+target.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/customvideosurface/customvideoitem
 sources.files = $$SOURCES $$HEADERS $$RESOURCES $$FORMS *.pro
-sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/customvideoitem
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/customvideosurface/customvideoitem
 
 INSTALLS += target sources

examples/customvideosurface/customvideosurface.pro

@@ -1,3 +1,8 @@
 TEMPLATE = subdirs
 
 SUBDIRS += customvideoitem customvideowidget
+
+# install
+sources.files = customvideosurface.pro
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/customvideosurface
+INSTALLS += sources

examples/customvideosurface/customvideowidget/customvideowidget.pro

@@ -14,8 +14,8 @@ SOURCES = \
     videowidget.cpp \
     videowidgetsurface.cpp
 
-target.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/customvideowidget
+target.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/customvideosurface/customvideowidget
 sources.files = $$SOURCES $$HEADERS $$RESOURCES $$FORMS *.pro
-sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/customvideowidget
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/customvideosurface/customvideowidget
 
 INSTALLS += target sources

examples/declarative-camera/declarative-camera.pro

@@ -5,20 +5,9 @@ QT += quick qml multimedia
 
 SOURCES += qmlcamera.cpp
 
+# install
 target.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/declarative-camera
+sources.files = $$SOURCES *.pro images *.qml
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/declarative-camera
+INSTALLS += target sources
 
-qml.files = declarative-camera.qml \
-            CameraButton.qml \
-            CameraPropertyButton.qml \
-            CameraPropertyPopup.qml \
-            FocusButton.qml \
-            PhotoCaptureControls.qml \
-            PhotoPreview.qml \
-            VideoCaptureControls.qml \
-            VideoPreview.qml \
-            ZoomControl.qml \
-            images
-
-qml.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/declarative-camera
-
-INSTALLS += target qml

examples/declarative-radio/declarative-radio.pro

@@ -5,3 +5,8 @@ RESOURCES += declarative-radio.qrc
 
 OTHER_FILES += view.qml
 
+# install
+target.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/declarative-radio
+sources.files = $$SOURCES $$HEADERS $$RESOURCES *.pro doc view.qml
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/declarative-radio
+INSTALLS += target sources

examples/video/qmlvideo/qmlapplicationviewer/qmlapplicationviewer.pri

@@ -1,128 +1,5 @@
-sources.files = $$SOURCES $$HEADERS $$RESOURCES $OTHER_FILES *.pro *.pri
-sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/$${TARGET}
-INSTALLS += sources
-
 QT += qml quick
 
 SOURCES += $$PWD/qmlapplicationviewer.cpp
 HEADERS += $$PWD/qmlapplicationviewer.h
 INCLUDEPATH += $$PWD
-
-defineTest(qtcAddDeployment) {
-for(deploymentfolder, DEPLOYMENTFOLDERS) {
-    item = item$${deploymentfolder}
-    itemsources = $${item}.sources
-    $$itemsources = $$eval($${deploymentfolder}.source)
-    itempath = $${item}.path
-    $$itempath= $$eval($${deploymentfolder}.target)
-    export($$itemsources)
-    export($$itempath)
-    DEPLOYMENT += $$item
-}
-
-MAINPROFILEPWD = $$PWD
-
-win32 {
-    copyCommand =
-    for(deploymentfolder, DEPLOYMENTFOLDERS) {
-        source = $$MAINPROFILEPWD/$$eval($${deploymentfolder}.source)
-        source = $$replace(source, /, \\)
-        sourcePathSegments = $$split(source, \\)
-        target = $$OUT_PWD/$$eval($${deploymentfolder}.target)
-        target = $$replace(target, /$, )
-        target = $$target/$$last(sourcePathSegments)
-        target = $$replace(target, /, \\)
-        !isEqual(source,$$target) {
-            !isEmpty(copyCommand):copyCommand += &&
-            isEqual(QMAKE_DIR_SEP, \\) {
-                copyCommand += $(COPY_DIR) \"$$source\" \"$$target\"
-            } else {
-                source = $$replace(source, \\\\, /)
-                target = $$OUT_PWD/$$eval($${deploymentfolder}.target)
-                target = $$replace(target, \\\\, /)
-                copyCommand += test -d \"$$target\" || mkdir -p \"$$target\" && cp -r \"$$source\" \"$$target\"
-            }
-        }
-    }
-    !isEmpty(copyCommand) {
-        copyCommand = @echo Copying application data... && $$copyCommand
-        copydeploymentfolders.commands = $$copyCommand
-        first.depends = $(first) copydeploymentfolders
-        export(first.depends)
-        export(copydeploymentfolders.commands)
-        QMAKE_EXTRA_TARGETS += first copydeploymentfolders
-    }
-} else:unix {
-    maemo5 {
-        desktopfile.files = $${TARGET}.desktop
-        desktopfile.path = /usr/share/applications/hildon
-        icon.files = $${TARGET}64.png
-        icon.path = /usr/share/icons/hicolor/64x64/apps
-    } else:!isEmpty(MEEGO_VERSION_MAJOR) {
-        desktopfile.path = /usr/share/applications
-        icon.files = $${TARGET}80.png
-        icon.path = /usr/share/icons/hicolor/80x80/apps
-    } else { # Assumed to be a Desktop Unix
-        copyCommand =
-        for(deploymentfolder, DEPLOYMENTFOLDERS) {
-            source = $$MAINPROFILEPWD/$$eval($${deploymentfolder}.source)
-            source = $$replace(source, \\\\, /)
-            macx {
-                target = $$OUT_PWD/$${TARGET}.app/Contents/Resources/$$eval($${deploymentfolder}.target)
-            } else {
-                target = $$OUT_PWD/$$eval($${deploymentfolder}.target)
-            }
-            target = $$replace(target, \\\\, /)
-            target = $$replace(target, /$, )
-            sourcePathSegments = $$split(source, /)
-            targetFullPath = $$target/$$last(sourcePathSegments)
-            !isEqual(source,$$targetFullPath) {
-                !isEmpty(copyCommand):copyCommand += &&
-                copyCommand += $(MKDIR) \"$$target\"
-                copyCommand += && $(COPY_DIR) \"$$source\" \"$$target\"
-            }
-        }
-        !isEmpty(copyCommand) {
-            copyCommand = @echo Copying application data... && $$copyCommand
-            copydeploymentfolders.commands = $$copyCommand
-            first.depends = $(first) copydeploymentfolders
-            export(first.depends)
-            export(copydeploymentfolders.commands)
-            QMAKE_EXTRA_TARGETS += first copydeploymentfolders
-        }
-    }
-    installPrefix = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/$${TARGET}
-    !isEmpty(MEEGO_VERSION_MAJOR): installPrefix = /opt/$${TARGET}
-    for(deploymentfolder, DEPLOYMENTFOLDERS) {
-        item = item$${deploymentfolder}
-        itemfiles = $${item}.files
-        $$itemfiles = $$eval($${deploymentfolder}.source)
-        itempath = $${item}.path
-        $$itempath = $${installPrefix}/$$eval($${deploymentfolder}.target)
-        export($$itemfiles)
-        export($$itempath)
-        INSTALLS += $$item
-    }
-
-    !isEmpty(desktopfile.path) {
-        export(icon.files)
-        export(icon.path)
-        export(desktopfile.files)
-        export(desktopfile.path)
-        INSTALLS += icon desktopfile
-    }
-
-    target.path = $${installPrefix}
-    export(target.path)
-    INSTALLS += target
-}
-
-export (ICON)
-export (INSTALLS)
-export (DEPLOYMENT)
-export (TARGET.EPOCHEAPSIZE)
-export (TARGET.CAPABILITY)
-export (LIBS)
-export (QMAKE_EXTRA_TARGETS)
-}
-

examples/video/qmlvideo/qmlvideo.pro

@@ -1,21 +1,21 @@
 TEMPLATE = app
 TARGET = qmlvideo
 
-SOURCES += main.cpp
+LOCAL_SOURCES = main.cpp
-HEADERS += trace.h
+LOCAL_HEADERS = trace.h
+
+SOURCES += $$LOCAL_SOURCES
+HEADERS += $$LOCAL_HEADERS
 RESOURCES += qmlvideo.qrc
 
-qml_folder.source = qml/qmlvideo
-qml_folder.target = qml
-DEPLOYMENTFOLDERS = qml_folder
-
-images_folder.source = images
-images_folder.target =
-DEPLOYMENTFOLDERS += images_folder
-
 SNIPPETS_PATH = ../snippets
 include($$SNIPPETS_PATH/performancemonitor/performancemonitordeclarative.pri)
-performanceItemAddDeployment()
 
 include(qmlapplicationviewer/qmlapplicationviewer.pri)
-qtcAddDeployment()
+
+# install
+target.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/video/qmlvideo
+sources.files = $$LOCAL_SOURCES $$LOCAL_HEADERS $$RESOURCES *.pro images qmlapplicationviewer qmlvideo.png qml qmlvideo.svg
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/video/qmlvideo
+INSTALLS += target sources
+

examples/video/qmlvideofx/qmlapplicationviewer/qmlapplicationviewer.pri

@@ -1,128 +1,7 @@
-sources.files = $$SOURCES $$HEADERS $$RESOURCES $OTHER_FILES *.pro *.pri
-sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/$${TARGET}
-INSTALLS += sources
-
 QT += quick
 
 SOURCES += $$PWD/qmlapplicationviewer.cpp
 HEADERS += $$PWD/qmlapplicationviewer.h
 INCLUDEPATH += $$PWD
 
-defineTest(qtcAddDeployment) {
-for(deploymentfolder, DEPLOYMENTFOLDERS) {
-    item = item$${deploymentfolder}
-    itemsources = $${item}.sources
-    $$itemsources = $$eval($${deploymentfolder}.source)
-    itempath = $${item}.path
-    $$itempath= $$eval($${deploymentfolder}.target)
-    export($$itemsources)
-    export($$itempath)
-    DEPLOYMENT += $$item
-}
-
-MAINPROFILEPWD = $$PWD
-
-win32 {
-    copyCommand =
-    for(deploymentfolder, DEPLOYMENTFOLDERS) {
-        source = $$MAINPROFILEPWD/$$eval($${deploymentfolder}.source)
-        source = $$replace(source, /, \\)
-        sourcePathSegments = $$split(source, \\)
-        target = $$OUT_PWD/$$eval($${deploymentfolder}.target)
-        target = $$replace(target, /$, )
-        target = $$target/$$last(sourcePathSegments)
-        target = $$replace(target, /, \\)
-        !isEqual(source,$$target) {
-            !isEmpty(copyCommand):copyCommand += &&
-            isEqual(QMAKE_DIR_SEP, \\) {
-                copyCommand += $(COPY_DIR) \"$$source\" \"$$target\"
-            } else {
-                source = $$replace(source, \\\\, /)
-                target = $$OUT_PWD/$$eval($${deploymentfolder}.target)
-                target = $$replace(target, \\\\, /)
-                copyCommand += test -d \"$$target\" || mkdir -p \"$$target\" && cp -r \"$$source\" \"$$target\"
-            }
-        }
-    }
-    !isEmpty(copyCommand) {
-        copyCommand = @echo Copying application data... && $$copyCommand
-        copydeploymentfolders.commands = $$copyCommand
-        first.depends = $(first) copydeploymentfolders
-        export(first.depends)
-        export(copydeploymentfolders.commands)
-        QMAKE_EXTRA_TARGETS += first copydeploymentfolders
-    }
-} else:unix {
-    maemo5 {
-        desktopfile.files = $${TARGET}.desktop
-        desktopfile.path = /usr/share/applications/hildon
-        icon.files = $${TARGET}64.png
-        icon.path = /usr/share/icons/hicolor/64x64/apps
-    } else:!isEmpty(MEEGO_VERSION_MAJOR) {
-        desktopfile.path = /usr/share/applications
-        icon.files = $${TARGET}80.png
-        icon.path = /usr/share/icons/hicolor/80x80/apps
-    } else { # Assumed to be a Desktop Unix
-        copyCommand =
-        for(deploymentfolder, DEPLOYMENTFOLDERS) {
-            source = $$MAINPROFILEPWD/$$eval($${deploymentfolder}.source)
-            source = $$replace(source, \\\\, /)
-            macx {
-                target = $$OUT_PWD/$${TARGET}.app/Contents/Resources/$$eval($${deploymentfolder}.target)
-            } else {
-                target = $$OUT_PWD/$$eval($${deploymentfolder}.target)
-            }
-            target = $$replace(target, \\\\, /)
-            target = $$replace(target, /$, )
-            sourcePathSegments = $$split(source, /)
-            targetFullPath = $$target/$$last(sourcePathSegments)
-            !isEqual(source,$$targetFullPath) {
-                !isEmpty(copyCommand):copyCommand += &&
-                copyCommand += $(MKDIR) \"$$target\"
-                copyCommand += && $(COPY_DIR) \"$$source\" \"$$target\"
-            }
-        }
-        !isEmpty(copyCommand) {
-            copyCommand = @echo Copying application data... && $$copyCommand
-            copydeploymentfolders.commands = $$copyCommand
-            first.depends = $(first) copydeploymentfolders
-            export(first.depends)
-            export(copydeploymentfolders.commands)
-            QMAKE_EXTRA_TARGETS += first copydeploymentfolders
-        }
-    }
-    installPrefix = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/$${TARGET}
-    !isEmpty(MEEGO_VERSION_MAJOR): installPrefix = /opt/$${TARGET}
-    for(deploymentfolder, DEPLOYMENTFOLDERS) {
-        item = item$${deploymentfolder}
-        itemfiles = $${item}.files
-        $$itemfiles = $$eval($${deploymentfolder}.source)
-        itempath = $${item}.path
-        $$itempath = $${installPrefix}/$$eval($${deploymentfolder}.target)
-        export($$itemfiles)
-        export($$itempath)
-        INSTALLS += $$item
-    }
-
-    !isEmpty(desktopfile.path) {
-        export(icon.files)
-        export(icon.path)
-        export(desktopfile.files)
-        export(desktopfile.path)
-        INSTALLS += icon desktopfile
-    }
-
-    target.path = $${installPrefix}
-    export(target.path)
-    INSTALLS += target
-}
-
-export (ICON)
-export (INSTALLS)
-export (DEPLOYMENT)
-export (TARGET.EPOCHEAPSIZE)
-export (TARGET.CAPABILITY)
-export (LIBS)
-export (QMAKE_EXTRA_TARGETS)
-}
 

examples/video/qmlvideofx/qmlvideofx.pro

@@ -1,27 +1,16 @@
 TEMPLATE = app
 TARGET = qmlvideofx
 
-SOURCES += filereader.cpp \
+LOCAL_SOURCES = filereader.cpp main.cpp
-           main.cpp
+LOCAL_HEADERS = filereader.h trace.h
-HEADERS += filereader.h \
+
-           trace.h
+SOURCES += $$LOCAL_SOURCES
+HEADERS += $$LOCAL_HEADERS
+
 RESOURCES += qmlvideofx.qrc
 
-qml_folder.source = qml/qmlvideofx
-qml_folder.target = qml
-DEPLOYMENTFOLDERS += qml_folder
-
-images_folder.source = images
-images_folder.target =
-DEPLOYMENTFOLDERS += images_folder
-
-shaders_folder.source = shaders
-shaders_folder.target =
-DEPLOYMENTFOLDERS += shaders_folder
-
 SNIPPETS_PATH = ../snippets
 include($$SNIPPETS_PATH/performancemonitor/performancemonitordeclarative.pri)
-performanceItemAddDeployment()
 
 maemo6: {
     DEFINES += SMALL_SCREEN_LAYOUT
@@ -29,4 +18,9 @@ maemo6: {
 }
 
 include(qmlapplicationviewer/qmlapplicationviewer.pri)
-qtcAddDeployment()
+
+# install
+target.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/video/qmlvideofx
+sources.files = $$LOCAL_SOURCES $$LOCAL_HEADERS $$RESOURCES *.pro images qmlapplicationviewer qmlvideofx.png shaders qml qmlvideofx.svg
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/video/qmlvideofx
+INSTALLS += target sources

examples/video/snippets/frequencymonitor/frequencymonitordeclarative.pri

@@ -1,15 +1,3 @@
 include($$PWD/frequencymonitor.pri)
 QT += qml
 SOURCES += $$PWD/frequencymonitordeclarative.cpp
-
-defineTest(frequencyItemAddDeployment) {
-    symbian: frequencyitem_folder.source = $$PWD/$$SNIPPETS_PATH/frequencymonitor/qml/frequencymonitor
-    else: frequencyitem_folder.source = $$SNIPPETS_PATH/frequencymonitor/qml/frequencymonitor
-    frequencyitem_folder.target = qml
-    DEPLOYMENTFOLDERS += frequencyitem_folder
-
-    export(frequencyitem_folder.source)
-    export(frequencyitem_folder.target)
-    export(DEPLOYMENTFOLDERS)
-}
-

examples/video/snippets/performancemonitor/performancemonitordeclarative.pri

@@ -3,18 +3,3 @@ include($$PWD/performancemonitor.pri)
 
 HEADERS += $$PWD/performancemonitordeclarative.h
 SOURCES += $$PWD/performancemonitordeclarative.cpp
-
-PERFORMANCE_ROOT = $$PWD
-
-defineTest(performanceItemAddDeployment) {
-    frequencyItemAddDeployment()
-
-    symbian: performanceitem_folder.source = $$PWD/$$SNIPPETS_PATH/performancemonitor/qml/performancemonitor
-    else: performanceitem_folder.source = $$SNIPPETS_PATH/performancemonitor/qml/performancemonitor
-    performanceitem_folder.target = qml
-    DEPLOYMENTFOLDERS += performanceitem_folder
-
-    export(performanceitem_folder.source)
-    export(performanceitem_folder.target)
-    export(DEPLOYMENTFOLDERS)
-}

examples/video/video.pro

@@ -1,3 +1,8 @@
 TEMPLATE = subdirs
 
 SUBDIRS += qmlvideo qmlvideofx
+
+# install
+sources.files = video.pro doc snippets
+sources.path = $$[QT_INSTALL_EXAMPLES]/qtmultimedia/video
+INSTALLS += sources